方法一：
<%
' ============================================
' 格式化时间(显示)
' 参数：n_Flag
'    1:"yyyy-mm-dd hh:mm:ss"
'    2:"yyyy-mm-dd"
'    3:"hh:mm:ss"
'    4:"yyyy年mm月dd日"
'    5:"yyyymmdd"
'    6:"mm-dd"
' ============================================
Function Format_Time(s_Time, n_Flag)
    Dim y, m, d, h, mi, s
    Format_Time = ""
    If IsDate(s_Time) = False Then Exit Function
    y = cstr(year(s_Time))
    m = cstr(month(s_Time))
    If len(m) = 1 Then m = "0" & m
    d = cstr(day(s_Time))
    If len(d) = 1 Then d = "0" & d
    h = cstr(hour(s_Time))
    If len(h) = 1 Then h = "0" & h
    mi = cstr(minute(s_Time))
    If len(mi) = 1 Then mi = "0" & mi
    s = cstr(second(s_Time))
    If len(s) = 1 Then s = "0" & s
    Select Case n_Flag
    Case 1
        ' yyyy-mm-dd hh:mm:ss
        Format_Time = y & "-" & m & "-" & d & " " & h & ":" & mi & ":" & s
    Case 2
        ' yyyy-mm-dd
        Format_Time = y & "-" & m & "-" & d
    Case 3
        ' hh:mm:ss
        Format_Time = h & ":" & mi & ":" & s
    Case 4
        ' yyyy年mm月dd日
        Format_Time = y & "年" & m & "月" & d & "日"
    Case 5
        ' yyyymmdd
        Format_Time = y & m & d
    case 6
        'mm-dd
        Format_Time = m & "-" & d
    case 7
        'hh:mm:ss dd-mm-yyyy
        Format_Time = h & ":" & mi & ":" & s& " " & d & "-" & m & "-" & y
    End Select
End Function
'dim shijian
'shijian=Format_Time(Now(),7)
'response.write "當前時間爲"&Cstr(shijian)
%>

方法二：
<%
'该函数作用：按指定参数格式化显示时间。
'numformat=1:将时间转化为yyyy-mm-dd hh:nn格式。
'numformat=2:将时间转化为yyyy-mm-dd格式。
'numformat=3:将时间转化为hh:nn格式。
'numformat=4:将时间转化为yyyy年mm月dd日 hh时nn分格式。
'numformat=5:将时间转化为yyyy年mm月dd日格式。
'numformat=6:将时间转化为hh时nn分格式。
'numformat=7:将时间转化为yyyy年mm月dd日 星期×格式。
'numformat=8:将时间转化为yymmdd格式。
'numformat=9:将时间转化为mmdd格式。

function formatdate(shijian,numformat)
dim ystr,mstr,dstr,hstr,nstr '变量含义分别为年字符串，月字符串，日字符串，时字符串，分字符串

if isnull(shijian) then
    numformat=0
else
    ystr=DatePart("yyyy",shijian)  
   
if DatePart("m",shijian)>9 then
      mstr=DatePart("m",shijian)
    else
      mstr="0"&DatePart("m",shijian)
    end if

    if DatePart("d",shijian)>9 then
      dstr=DatePart("d",shijian)
    else
      dstr="0"&DatePart("d",shijian)
    end if

    if DatePart("h",shijian)>9 then
      hstr=DatePart("h",shijian)
    else
      hstr="0"&DatePart("h",shijian)
    end if

    if DatePart("n",shijian)>9 then
      nstr=DatePart("n",shijian)
    else
      nstr="0"&DatePart("n",shijian)
    end if
end if

select case numformat
    case 0
   formatdate=""
case 1
   formatdate=ystr&"-"&mstr&"-"&dstr&" "&hstr&":"&nstr
case 2
   formatdate=ystr&"-"&mstr&"-"&dstr
case 3
   formatdate=hstr&":"&nstr
case 4
   formatdate=ystr&"年"&mstr&"月"&dstr&"日 "&hstr&"时"&nstr&"分"
case 5
   formatdate=ystr&"年"&mstr&"月"&dstr&"日"
case 6
   formatdate=hstr&"时"&nstr&"分"
case 7
   formatdate=ystr&"年"&mstr&"月"&dstr&"日 "&WeekdayName(Weekday(shijian))
case 8
   formatdate=right(ystr,2)&mstr&dstr
case 9
   formatdate=mstr&dstr
end select
end function

dim shijian
shijian=formatdate(Now(),9)
response.write "當前時間爲"&Cstr(shijian)
%>